Outro Gerar um executável a partir do winrar

[vncs.info]

Ola...eu tenho um programa, onde consigo gerar o executável dele pelo winrar, pelo procedimento padrão do winrar...sendo que preciso fazer uma versao atualizada do programa, e descobrir que posso gerar execultavel do winrar via linha de comando. Só nao conseguir achar os parâmetros....Alguém poderia me ajudar com isso

[ricardo_br]

O que você quer fazer gerar um executável a partir do winrar que extraia um arquivo?

 

Digamos que você tenha um arquivo chamado Arquivo01.txt e queira criar um executável que extraia esse mesmo arquivo Arquivo01.txt chamdo Programa.exe:

 

%programfiles%\winrar\rar.exe a -sfx Programa.exe Arquivo01.txt

 

 

[Eder Neumann]

não precisa nem usar linha de comando para isso...

[ricardo_br]

4 minutos atrás, Eder Neumann disse:

não precisa nem usar linha de comando para isso...

Parece que ele quer saber como fazer pelo prompt pois já sabe fazer pelo meio padrão.

[Eder Neumann]

agora, ricardo_br disse:

Parece que ele quer saber como fazer pelo prompt pois já sabe fazer pelo meio padrão.

verdade, não tinha compreendido o texto dele.  

 

[vncs.info]

@ricardo_br é isso mesmo, pelo modo padrão eu ja faço....Eu pego o executável e gero um instalador com o icone e logo do programa que meus alunos criam, e ensinam eles gerarem pelo winrar de forma padrão....

Agora pra acelerar o processo, me disseram que posso gerar um instalador do meu programa por linha de comando...Ex: entro na pasta do executável e faço um comando "rar.exe, e mais alguma coisa", e poder gerar meu instalador....

[ricardo_br]

Sim você pode criar um arquivo .bat que faz isso automáticamente. O nome do executável e do icone é sempre o mesmo ou ele muda de nome sempre?

[vncs.info]

No caso os nomes vão ser sempre o mesmo... esse comando que quero aprender a fazer.....

[ricardo_br]

A forma que eu postei é a forma simples de fazer 

%programfiles%\winrar\rar.exe a -sfx Programa.exe Programa2.exe

 

Ele gera um arquivo autoextraível chamado Programa.exe e dentro dele vai ter o programa do aluno, digamos "Programa2.exe quando você executa Programa.exe ele vai abrir um assistente para extrair o programa2.exe.

 

Vou tentar postar a sequência completa aqui mais tarde....

[ricardo_br]

Olá vou mostrar como fazer inserindo os comandos manualmente no prompt de comando e também criando um arquivo batch que nada mais é do que um arquivo de texto com comandos do prompt que serão executados em lote um atrás do outro:

 

* Meu cenário é assim ajuste para as suas necessidades:

 

A pasta onde estão os arquios que serão incluidos no arquivo de instalação (sfx):

%userprofile%\desktop\Teste

 

Onde será criado o arquivo de Instalação sfx:

%userprofile%\desktop\setup.exe

 

Para onde serão extraídos os arquivos do arquivo sfx:

%programfiles%\TesteCCleaner

 

O arquivo que vai fazer a instalação:

%userprofile%\desktop\Teste\ccsetup566.exe

 

O arquivo de icone:

%userprofile%\desktop\Teste\drinking.ico

 

Inserindo os comandos manualmente no Prompt de comando:

 

Insira os seguintes comandos no prompt de comando um atrás do outro ajustando respectivamente conforme o seu cenário e necessidades:

 

echo Path=%Programfiles%\TesteCCleaner>"%temp%\opções.txt"
echo Silent=^1>>"%temp%\opções.txt"
echo Setup=%userprofile%\desktop\Teste\ccsetup566.exe>>%temp%\opções.txt

"%programfiles%\winrar\rar.exe" a -c -cfg- -ep1 -s -r -sfx -iicon"%userprofile%\desktop\Teste\drinking.ico" -y "-z%TEMP%\opções.txt" "%userprofile%\desktop\setup.exe" "%userprofile%\desktop\Teste\*"

del "%temp%\opções.txt"

 

Criando um arquivo batch para automatizar o processo:

 

1. Abra o bloco de notas, copie e cole o código abaixo e ajuste conforme as suas necessidades e salve ele com extensão .bat:

 

@echo off
chcp 1252 > Nul

:: Especifique aqui o caminho para on rar.exe:
set "Rar=%programfiles%\winrar\rar.exe"

:: Especifique aqui onde estão os arquivos que deverão ser incluidos no arquivo sfx:
set Fonte=%userprofile%\desktop\Teste\*

:: Especifique aqui o caminho para onde os arquivos devem ser extraídos:
set CExtracao=%Programfiles%\TesteCCleaner

:: Especifique aqui o arquivo de instalação:
set CInstalacao=%userprofile%\desktop\Teste\ccsetup566.exe

:: Especifique o arquivo sfx que devera ser criado:
set SFX=%userprofile%\desktop\setup.exe

:: Especifique aqui o icone do Arquivo SFX:
set Icone=%userprofile%\desktop\Teste\drinking.ico

echo Path=%CExtracao%>"%temp%\opções.txt"
echo Silent=^1>>"%temp%\opções.txt"
echo Setup=%CInstalacao%>>%temp%\opções.txt

"%Rar%" a -c -cfg- -ep1 -s -r -sfx -iicon"%Icone%" -y "-z%TEMP%\opções.txt" "%SFX%" "%Fonte%"

del "%temp%\opções.txt"

Vou deixar o link do batch aqui porque parece que a correção ortográfica do navegador ou do Clube do Hardware modificou o código um pouco: Instalador.zip

 

 

 

Alguns links em inglês que me ajudaram e que achei interessante:

 

How to create self-extracting RAR archive not showing anything on execution?

 

How can I create an auto-executing, WinRar SFX file from a batch file?

 

Create WinRAR SFX with admin rights by command line

 

 

 

 

[vncs.info]

@ricardo_br muito obrigado por esse socorro....eu vou testar aqui e mando o resultado....ate aqui obrigado a todos...