VisualG Associação de aluno com a sua nota

[TEC897546]

Pessoal, como eu faço para relacionar o nome do aluno com a nota dele ? eu preciso que o algoritmo mostre a maior nota e o nome do aluno que conseguiu essa nota. 

 

Algoritmo "semnome"

Var
   alu,contador,na,ndal: inteiro
   maior: real
   nal:caractere

Inicio
   escreval("---------------------")
   escreval("     Escola Santa    ")
   escreval("---------------------")
   escreval("Quantos alunos a turma tem ?")
   leia(alu)
   contador<-1
   na <- 1
   maior<-0
   enquanto (contador<=alu) faca
      escreval("---------------------------")
      escreval  ("Aluno",na)
      escreva   ("Nome do aluno:")
      leia(nal)
      escreva   ("Nota do aluno:")
      leia(ndal)
      na<-na + 1
      contador <- contador + 1
      se (ndal>maior) entao
         maior <- ndal
      fimse
   fimenquanto
   escreval ("A maior nota foi",maior," essa é a nota de "AQUI EU DEVERIA COLOCAR O NOME DO ALUNO, MAS COMO EU RELACIONO A MAIOR NOTACOM O NOME ?)
Fimalgoritmo

 

[Simon Viegas]

@TEC897546, basicamente só precisa também salvar o nome após descobrir uma nota maior que a atual.

 

Outros pontos... como sugestão:

• use nomenclaturas de variáveis mais sugestivas;
• não precisa ficar repetindo "do aluno" ao ler os dados;
• como é um loop de quantidade pré-determinadas, melhor utilizar para/faca, em detrimento do enquanto/faca.
• o "maior" deve ser do mesmo tipo do que ele está referenciando. (ou ambos seriam inteiros, ou ambos seriam real, por exemplo);
• na e contador são análogos... não precisaria de duas variáveis para fazer a mesma coisa.

 

Segue um exemplo:
 

algoritmo "Maior nota dos alunos"
var
   totalAlunos, contador :inteiro
   notaAluno, maiorNota :real
   nomeAluno, nomeMaiorNota :caractere

inicio
   escreval("---------------------")
   escreval("     Escola Santa    ")
   escreval("---------------------")
   escreval("Quantos alunos a turma tem ?")
   leia(totalAlunos)

   maiorNota <- 0 //no VisualG não precisaria zerar, mais é bom deixar!
   contador <- 0 //no VisualG não precisaria zerar, mais é bom deixar!

   enquanto (contador < totalAlunos) faca
      contador <- contador + 1
      escreval("---------------------------")
      escreval("Aluno ", contador)
      escreva ("Nome : ")
      leia(nomeAluno)
      escreva ("Nota : ")
      leia(notaAluno)

      se (notaAluno > maiorNota) entao
         maiorNota <- notaAluno
         nomeMaiorNota <- nomeAluno
      fimse
      
   fimEnquanto
   escreval ("A maior nota foi ", maiorNota:1:2, ". Essa é a nota de ", nomeMaiorNota)
fimAlgoritmo

 

[TEC897546]

@Simon Viegas Muito obrigado pelo feedback, irei colocar esses pontos nos meus algoritmos futuros. eu usei enquanto/faca porque só estudei essas até o momento.