Visual Basic Copiar uma aba com base em outra e renomear com inputbox ou formulário

[C.Lima2021]

Gostaria de um código onde em um formulário, a pessoa coloque o nome do produto e o vba crie uma aba com esse nome, o  userform ou inputbox, essa nova aba tem que ser uma cópia da aba "dados" com o nome inserido pelo usuário no userform ou inputbox. Podem me ajudar?

[Midori]

Use o método copy e depois coloque o nome do produto na planilha ativa, p.ex,

 

Sheets("Dados").Copy Before:=Sheets("Dados")
ActiveSheet.Name = "Teste"

 

Onde está Teste coloque o nome informando no controle do seu formulário

[C.Lima2021]

@Midori muito obrigada usei o seu código adaptando para inputbox e funcionou

Como fazer agora para tirar erro do inputbox não respondido?

 

 ou com o  nome repetido?

[Midori]

26 minutos atrás, C.Lima2021 disse:

Como fazer agora para tirar erro do inputbox não respondido?

Faça um If na variável Renomear. Se não tiver nenhum texto é porque o input foi cancelado ou o usuário não digitou nada.

 

Se tentar renomear uma aba com nome repetido vai dar o erro 9. Uma alternativa é criar uma função para tratar esse erro antes de tentar copiar, p.ex,

 

Function PlanilhaExiste(Nome As String) As Boolean
    On Error Resume Next
    ThisWorkbook.Sheets(Nome).Activate
    PlanilhaExiste = Not Err.Number = 9
End Function

 

E na Sub do input,

If Renomear <> "" Then
    If Not PlanilhaExiste(Renomear) Then
        Sheets("BASE").Copy Before:=Sheets("BASE")
        ActiveSheet.Name = Renomear
    Else
        MsgBox "A planilha " & Renomear & " já existe", vbInformation
    End If
End If

 

[C.Lima2021]

@Midori Certo, poderia colocar todo o código para eu ver como ficaria?

Coloquei o meu e dá erro!

[Midori]

O código completo pode ser assim,

 

Sub Macro()
    Dim Renomear As String
    
    Renomear = InputBox("Produto")
    
    If Renomear <> "" Then
        If Not PlanilhaExiste(Renomear) Then
            Sheets("BASE").Copy Before:=Sheets("BASE")
            ActiveSheet.Name = Renomear
        Else
            MsgBox "A planilha " & Renomear & " já existe", vbInformation
        End If
    End If
End Sub

Function PlanilhaExiste(Nome As String) As Boolean
    On Error Resume Next
    ThisWorkbook.Sheets(Nome).Activate
    PlanilhaExiste = Not Err.Number = 9
End Function