VisualG Como proceder com esse codigo no visualg?

[NinjaDoBairro]

Boa noite, eu preciso por no meu código o nome da pessoa que tem o maior salario e o menor salario, como faco pra incluir essa informação?

 

escreval("Digite o nome do primeiro funcionario: ")
leia(nome1)
escreval("Digite o salario do primeiro funcionario: ")
leia(s1)

//aqui em cima continua ate o quinto nome/salario

   media <- (s1+s2+s3+s4+s5)/5

   se (s1 >= s2) entao
      maior <- s1
      menor <- s2
   senao
      maior <- s2
      menor <- s1
   fimse

   se (s3>=maior) entao
      maior <- s3
   senao
      se (menor>=s3) entao
         menor <- s3
      fimse
   fimse

   se (s4>=maior) entao
      maior <- s4
   senao
      se (menor>=s4) entao
         menor <- s4
      fimse
   fimse

   se (s5>=maior) entao
      maior <- s5
   senao
      se (menor>=s5) entao
         menor <- s5
      fimse
   fimse
   
   Escreval("O maior salario é: ",maior)
   Escreval("O menor salario é: ",menor)
   Escreval("A media salarial é de: ",media)

 

[devair1010]

@NinjaDoBairro     melhor postar o código todo , pois sem as variáveis não tem jeito de testar ,  e

[NinjaDoBairro]

segue o que falta:

Algoritmo "salario"
Var
   // Seção de Declarações das variáveis

   nome1, nome2, nome3, nome4, nome5 : caractere
   s1, s2, s3, s4, s5, media, maior, menor : real

Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...


   escreval("Digite o nome do primeiro funcionario: ")
   leia(nome1)
   escreval("Digite o salario do primeiro funcionario: ")
   leia(s1)
   escreval("Digite o nome do segundo funcionario: ")
   leia(nome2)
   escreval("Digite o salario do segundo funcionario: ")
   leia(s2)
   escreval("Digite o nome do terceiro funcionario: ")
   leia(nome3)
   escreval("Digite o salario do terceiro funcionario: ")
   leia(s3)
   escreval("Digite o nome do quarto funcionario: ")
   leia(nome4)
   escreval("Digite o salario do quarto funcionario: ")
   leia(s4)
   escreval("Digite o nome do quinto funcionario: ")
   leia(nome5)
   escreval("Digite o salario do quinto funcionario: ")
   leia(s5)

 

[devair1010]

@NinjaDoBairro @NinjaDoBairro    para incluir o nome junto ao menor salario  ,  ao encontrar o menor salario  coloque junto o nome da pessoa ,  porém  usando variáveis simples , como as que você está usando , vai ser muito trabalhoso , e são apenas cinco pessoas , mas e se fossem 1001 pessoas ?   ,  isso seria quase impossível ,   e então seria melhor usar vetor e laços de repetição  , para facilitar as coisas ,  mas seu código , seguindo sua ideia , para o maior  poderia ser assim :

Algoritmo "salario"
Var
  nome1, nome2, nome3, nome4, nome5       : caractere
  nome_m_sal : caractere
  s1, s2, s3, s4, s5, media, maior, menor : real
Inicio
   escreval("Digite o nome do primeiro funcionario: ")
   leia(nome1)
   escreval("Digite o salario do primeiro funcionario: ")
   leia(s1)
   maior := s1
   nome_m_sal := nome1
   escreval("Digite o nome do segundo funcionario: ")
   leia(nome2)
   escreval("Digite o salario do segundo funcionario: ")
   leia(s2)
   se s2 > maior entao
     maior := s2
     nome_m_sal := nome2
   fimse
   escreval("Digite o nome do terceiro funcionario: ")
   leia(nome3)
   escreval("Digite o salario do terceiro funcionario: ")
   leia(s3)
   se s3 > maior entao
     maior := s3
     nome_m_sal := nome3
   fimse
   escreval("Digite o nome do quarto funcionario: ")
   leia(nome4)
   escreval("Digite o salario do quarto funcionario: ")
   leia(s4)
   se s4 > maior entao
     maior := s4
     nome_m_sal := nome4
   fimse
   escreval("Digite o nome do quinto funcionario: ")
   leia(nome5)
   escreval("Digite o salario do quinto funcionario: ")
   leia(s5)
   se s5 > maior entao
     maior := s5
     nome_m_sal := nome5
   fimse
   Escreval("O maior salario é -----: ",maior:1   )
   escreval("pertencente a ---------: ",nome_m_sal)
   Escreval("O menor salario é -----: ",menor : 1 )
   Escreval("A media salarial é de -: ",media : 1 )
Fimalgoritmo

 e para o menor seria a mesma coisa ;

[devair1010]

@NinjaDoBairro    e se você puder usar vetores , poderia ser assim  :

algoritmo "maior e menor salario"
// Disciplina  : [ Linguagem e Lógica de Programação ]
// Professor   : Antonio Carlos Nicolodi 
// Descrição   : Aqui você descreve o que o programa faz! ( função )
// Autor(a)    : Nome do( a ) aluno( a )
// Data atual  : 22/06/2022
var
  nomes        : vetor[1..5] de caractere
  salarios     : vetor[1..5] de real
  media, maior : real
  menor , aux  : real
  a, b         : inteiro
  bux          : caractere
inicio
  para a de 1 ate 5 faca
    escreva("Digite o nome do ",a:1,"º funcionario ----: ")
    leia( nomes[ a ] )
    escreva("Digite o salario do ",a:1,"º funcionario -: ")
    leia( salarios[ a ] )
    media := media + salarios[a]    // media eh a soma divido pela qtd de func
  fimpara                           // pegou e guardoU os Nomes e SaLarios
  para   a de     1 ate 4 faca      // metodo "AnchorSort" de OrdeNacao de
    para b de a + 1 ate 5 faca      // vetores em orDem decrescente
      se salarios[a] < salarios[b] entao
        aux         := salarios[a]
        salarios[a] := salarios[b]
        salarios[b] :=         aux  // organiza os salarios
                                    // Amarra o salario ao nome do func
        bux         :=    nomes[a]
        nomes[a]    :=    nomes[b]
        nomes[b]    :=         bux  // organiza tambem os Nomes
      fimse
    fimpara
  fimpara                           // colocou os salarios em ordem decRescentes
  media <- media / 5
  maior := salarios[1]              // o Maior esta na pos 1 do vetor
  menor := salarios[5]              // o MenoR esta na pos 5 Ultima do Vetor
  escreval
  escreval
  escreval("O maior salario  é ----: R$ ",maior:7:2," perTecente a ",nomes[1] )
  escreval("O menor salario  é ----: R% ",menor:7:2," perTecente a ",nomes[5] )
  escreval("A media salarial é de -: R$ ",media:7:2                           )
  escreval
  escreval
fimalgoritmo

 

[NinjaDoBairro]

Perfeito @devair1010, deu certo, muito obrigado.