VisualG Visualg - voltar ao comando (voltar a tela)

[Marlon Gramacho]

Galera é o seguinte fiz o código porém quero que apareça p/ o usuário logo após digitar o valor a opção de voltar ao menu mas é claro que ficando ao critério do usuário, ou seja, usuário digitando a opção "S" volta pra tela perguntando "Informe o nível do mar:"

 

EXEMPLO ABAIXO:

Escreva ("Voltar para o menu (S/N)?")
Leia (op)
Se op="S" entao

 

var
   mar: real

inicio
...
         escreval("Informe o nível do mar: ")
         leia(mar)

         escolha mar
         caso 0 ate 0,69
            escreval("bom")
         caso 0,7
            escreval ("atenção II")
         caso 0,8
            escreval("atenção III")
         caso 0,9
            escreval("ALERTA MAXIMO")
         fimEscolha
      fimEnquanto
   fimProcedimento
fimAlgoritmo

 

[devair1010]

@Marlon Gramacho     não  tem nenhum comando para voltar atrás ou ir para algum ponto a frente na execucao do codigo  no visualG ,  como o "goto" em outras linguagens  ,  entao o que se pode fazer eh usar um laco de repeticao , que irah repetir o que esteja dentro desse bloco  ,     e  poderia ser o repita / ate  , assim

 

inicio

  repita

    escreval ("Informe o nível do mar: ")
    leia (mar)
    escolha (mar)

    caso 0 ate 0,69
      escreval ("bom")

    caso 0,7
      escreval ("atenção II")

    caso 0,8
      escreval ("atenção III")

    caso 0,9
      escreval ("ALERTA MAXIMO")
  fimescolha

  Escreva ("Voltar para o menu (S/N)?")
Leia (op)

ate op = "n"

[Marlon Gramacho]

Cara teria outra forma de fazer isso acontecer? O meu tá dando erro na Variável

 

Var
poluicao : real

Inicio
      Escreval     ("____________________________________________________________")
      Escreval ("        Secretaria Municipal de Meio Ambiente               ")
      Escreval ("                         SMMA                               ")
      Escreval ("____________________________________________________________")


      Escreval ("Software Controlador de Emissão de Gases Poluentes")
      Escreval ("           CEGP - Vitoria da Conquista            ")

      Escreval ("                                                  ")

repita
escreval ("Informe o nível de poluição: ")
leia (poluicao)
escolha (poluicao)

caso 0 ate 0,69
escreval ("Todas as empresas podem funcionar normalmente")


caso 0,7
escreval ("1º grupo de empresas com suas atividades suspensas")

caso 0,8
escreval ("1º e 2º grupo de empresas com suas atividades suspensas")

caso 0,9
escreval ("1º, 2º e 3º grupo de empresas com suas atividades suspensas")

Escreva ("Voltar para o menu (S/N)?")
Leia (op)
ate op = "n"

fimescolha

fimprocedimento

Fimalgoritmo

[devair1010]

@Marlon Gramacho    você colocou o comando "ate"  dentro do bloco de "escolha / fimescolha"   ,  e experimente usar o botão Code  "<>"  , que está desenhado lá na barra de ferramentas da janela de postar 

e  seu código poderia  ser assim  :

Algoritmo "voltar ao Menu"
// Data atual  : 28/06/2022
Var
  poluicao : real
  op       : caractere
Inicio
  escreval("____________________________________________________________")
  escreval("        Secretaria Municipal de Meio Ambiente               ")
  escreval("                         SMMA                               ")
  escreval("____________________________________________________________")
  escreval("Software Controlador de Emissão de Gases Poluentes")
  escreval("           CEGP - Vitoria da Conquista            ")
  escreval
  repita
    escreval ("Informe o nível de poluição: ")
    leia( poluicao )
    escolha poluicao
    caso 0 ate 0,69
      escreval ("Todas as empresas podem funcionar normalmente")
    caso 0,7
      escreval ("1º grupo de empresas com suas atividades suspensas")
    caso 0,8
      escreval ("1º e 2º grupo de empresas com suas atividades suspensas")
    caso 0,9
      escreval ("1º, 2º e 3º grupo de empresas com suas atividades suspensas")
    fimescolha
    escreva ("Voltar para o menu ( S / N ) ? ")
    leia (op)
  ate op = "n"
Fimalgoritmo

 

[Marlon Gramacho]

Copiei esse código e continua apresentando o mesmo erro 

[devair1010]

@Marlon Gramacho   está informando erro na linha 7 , e nesse código que postei a linha 7 não tem a palavra "var".    poste o código que você está tentando compilar .

[Simon Viegas]

@Marlon Gramacho e @devair1010, escolha não funciona para números reais. Nesse caso, poderiamse utilizar uma cadeia de se/senao.

 

 

Outro ponto que números decimais no texto do código ficam com "." em vez de "," (ex.: 0.85). Já para digitar tanto faz (ex.: 0.85 ou 0,85)

 

Exemplo de código:

algoritmo "Nível de Emissão de Gastas Poluentes"
var
   nivelPoluicao : real
   op : caractere

inicio
   repita
      escrevaL("____________________________________________________________")
      escrevaL("        Secretaria Municipal de Meio Ambiente               ")
      escrevaL("                         SMMA                               ")
      escrevaL("____________________________________________________________")
      escrevaL(" Software Controlador de Emissão de Gases Poluentes")
      escrevaL("            CEGP - Vitória da Conquista            ")
      escrevaL("                                                   ")
      escreva ("Informe o nível de poluição: ")
      leia(nivelPoluicao)

      se (nivelPoluicao <= 0.69) entao
         escrevaL("Todas as empresas podem funcionar normalmente")
      senao
         se (nivelPoluicao <= 0.7) entao
            escrevaL("1º grupo de empresas com suas atividades suspensas")
         senao
            se (nivelPoluicao <= 0.8) entao
               escrevaL("1º e 2º grupo de empresas com suas atividades suspensas")
            senao
               se (nivelPoluicao <= 0.9) entao
                  escrevaL("1º, 2º e 3º grupo de empresas com suas atividades suspensas")
               senao
                  escrevaL("Nível inválido")
               fimSe
            fimSe
         fimSe
      fimSe

      escreva ("Voltar para o menu (S/N)?")
      leia(op)
   ate op = "n"
fimAlgoritmo

Adendo: para saber os parâmetros corretos, precisaria do enunciado completo da questão.